[翻译]]ARM汇编简介（四）载入/存储多个值，入栈和出栈

最近心情不错，抓紧时间继续学习并翻译~https://azeria-labs.com/arm-conditional-execution-and-branching-part-5/

LOAD/STORE MULTIPLE 载入/存储多个值

Sometimes it is more efficient to load (or store) multiple values at once. For that purpose we use LDM (load multiple) and STM (store multiple). These instructions have variations which basically differ only by the way the initial address is accessed. This is the code we will use in this section. We will go through each instruction step by step. 

有时，一次性加载（或存储）多个值更有效率。因此，我们需要使用LDM（载入多个值）和STM（存储多个值）。这些指令基于起始地址的不同，有不同的形式。下面是我们将在本节中将会使用的代码。我们将一步一步地完成每一个指令。

.data

array_buff:

 .word 0x00000000             /* array_buff[0] */

 .word 0x00000000             /* array_buff[1] */

 .word 0x00000000             /* array_buff[2]. This element has a relative address of array_buff+8 这里存储了array_buff+8的相对地址*/

 .word 0x00000000             /* array_buff[3] */

 .word 0x00000000             /* array_buff[4] */

.text

.global _start

_start:

 adr r0, words+12             /* address of words[3] -> r0  将words[3]的地址传送给r0 */

 ldr r1, array_buff_bridge    /* address of array_buff[0] -> r1  将 array_buff[0]的地址给r1*/

 ldr r2, array_buff_bridge+4  /* address of array_buff[2] -> r2   将 array_buff[2]的地址给r2*/

 ldm r0, {r4,r5}              /* words[3] -> r4 = 0x03; words[4] -> r5 = 0x04  */

 stm r1, {r4,r5}              /* r4 -> array_buff[0] = 0x03; r5 -> array_buff[1] = 0x04 */

 ldmia r0, {r4-r6}            /* words[3] -> r4 = 0x03, words[4] -> r5 = 0x04; words[5] -> r6 = 0x05; */

 stmia r1, {r4-r6}            /* r4 -> array_buff[0] = 0x03; r5 -> array_buff[1] = 0x04; r6 -> array_buff[2] = 0x05 */

 ldmib r0, {r4-r6}            /* words[4] -> r4 = 0x04; words[5] -> r5 = 0x05; words[6] -> r6 = 0x06 */

 stmib r1, {r4-r6}            /* r4 -> array_buff[1] = 0x04; r5 -> array_buff[2] = 0x05; r6 -> array_buff[3] = 0x06 */

 ldmda r0, {r4-r6}            /* words[3] -> r6 = 0x03; words[2] -> r5 = 0x02; words[1] -> r4 = 0x01 */

 ldmdb r0, {r4-r6}            /* words[2] -> r6 = 0x02; words[1] -> r5 = 0x01; words[0] -> r4 = 0x00 */

 stmda r2, {r4-r6}            /* r6 -> array_buff[2] = 0x02; r5 -> array_buff[1] = 0x01; r4 -> array_buff[0] = 0x00 */

 stmdb r2, {r4-r5}            /* r5 -> array_buff[1] = 0x01; r4 -> array_buff[0] = 0x00; */

 bx lr

words:

 .word 0x00000000             /* words[0] */

 .word 0x00000001             /* words[1] */

 .word 0x00000002             /* words[2] */

 .word 0x00000003             /* words[3] */

 .word 0x00000004             /* words[4] */

 .word 0x00000005             /* words[5] */

 .word 0x00000006             /* words[6] */

array_buff_bridge:

 .word array_buff             /* address of array_buff, or in other words - array_buff[0] */

 .word array_buff+8           /* address of array_buff[2] */

Before we start, keep in mind that a .word refers to a data (memory) block of 32 bits = 4 BYTES. This is important for understanding the offsetting. So the program consists of .data section where we allocate an empty array (array_buff) having 5 elements. We will use this as a writable memory location to STORE data. The .text section contains our code with the memory operation instructions and a read-only data pool containing two labels: one for an array having 7 elements, another for “bridging” .text and .data sections so that we can access the array_buff residing in the .data section.

开始前，请记住.word指向了一个32位共计4字节的数据（内存）区块，这对于理解代码中的偏移很重要。程序中包含了.data区段，在此我们开辟了一个有5个元素的空数组array_buff。.text段包含了由内存操作指令构成的代码，和一个包含了两个标签的只读数据池，其中一个标签规定了一个具有7个元素的数组，另一个标签起到了“桥接”.text区段和.data区段的作用，我们可以用它访问.data区段的array_buffer。